Q): What is passing by reference?

Q): How should dates be implemented so they work with other language and country formats ?

  strTodaysDate = Format[$](Now,"Short Date")

As a side note, Microsoft has taken much heat on the newsgroup for VB's bad support for internationalization! Just try to make a date literal in source code that works everywhere as little exercise. Answer elsewhere in this document.)

Q): Why does everyone say I should save in TEXT not BINARY?

A): Applies only to VB 3.0 and below: Actually, saving in binary mode is a bit faster, so why is it recommended to save in text?

If you save the source and project as text, it becomes ASCII (or really, ANSI) code that you can edit with any text edit or (if you are careful when you save) word processor. If you save in binary only, only the VB development environment, current or later versions, will understand the code. The Setup Wizard can not scan binary projects. Also, source documenters and other programming tools usually require text mode. If you use text, you can use a simple text editor (e.g. notepad) to cut and paste code from other source/form modules into your current project. Some 'tricks' (like making an array of one control into a single non-array control again) is easily done with an editor but not that easy in the environment. If you want to import the text files into your word processor. And, finally, if something goes wrong (only one byte is changed!) you may be out of luck in binary mode. In text mode you will more easily be able to fix it.

VB 4.0 and greater does not offer the option of saving in binary, saving us from a lot of problems.

Q): Is the Variant type slower than using other variable types?

A): Generally, yes, if we are talking numeric variable types. The Variant type also increases memory overhead. To test the speed difference, try the following piece of code in something like a button_click event and keep the debug window on the screen:

  Dim Va As Variant
  Dim In As Integer

  T1! = Timer
  For i% = 1 To 32767
      Va = i%
  Next

  T2! = Timer
  Debug.Print "With a variant: "; Format$((T2! - T1!), "0.0000")

  T1! = Timer
  For i% = 1 To 32767
      In = i%
  Next

  T2! = Timer
  Debug.Print "With an integer: "; Format$((T2! - T1!), "0.0000")

This test shows (on our test system using VB 6.0) that integers are 60% faster! However, for strings there were no real difference, or in some instances, variants were faster than strings for routines with heavy conversion usage. For best results in your application, test your routines directly. 

Q): How do I implement an incremental search in list/dir/combo/file boxes?

A): This is your lucky day. Dan Champagne (Dan_Champagne@dell.com) made some VB code (no DLLs are necessary!) which easily provides this feature for your application:

  ' Code by Dan Champagne
  ' 4/18/94
  ' This code can be used to do an incremental search in either a list box,
  ' dir, combo, or a file box. The following code is set for a file box with a
  ' different name, change all occurences of FILE1 with whatever you or VB has
  ' named your list, combo, dir, or file box. There are two places where you
  ' will need to change these. They are on the last couple of lines in the
  ' KeyPress code. Also, thanks to John Tarr for helping debug the code.
  '
  ' In a .BAS file, add the following:
  ' searchme$ is a global variable that will keep track of what the user has
  ' typed so far.

  Global searcme$
  Global Const WM_USER = &H400
  Global Const LB_SELECTSTRING = (WM_USER + 13)
  Global Const LB_FINDSTRING = (WM_USER + 16)

  Declare Function SendMessageByString& Lib "User32" ALIAS "SendMessage" _
  (ByVal hWnd%, ByVal wMsg%, ByVal wParam%, ByVal lParam$)

  ' In File1 under keydown, add the following:
  ' This checks if the user has pressed the up or down arrow.
  ' If they have, reset searchme$ to vbNullString.
  If KeyCode = 40 Or KeyCode = 38 Then
      searchme$ = vbNullString
  End If

  ' In File1 under lostfocus, pathchange, patternchange, and click add:
  ' If the user has done any of the above, reset searchme$
  searchme$ = vbNullString

  ' In File1 under KeyPress add:
  Dim result&

  Select Case KeyAscii
      Case 8  ' Backspace
          If searchme$ <> vbNullString Then
              searchme$ = Left$(searchme$, Len(searchme$) - 1)
          Else
              File1.ListIndex = 0
          End If
          KeyAscii = 0
          Exit Sub
      Case 27  ' Escape
          searchme$ = vbNullString
          KeyAscii = 0
          Exit Sub
      Case 13  ' Enter
          searchme$ = vbNullString
          KeyAscii = 0
          Exit Sub
      Case Asc("a") To Asc("z"), Asc("A") to Asc("Z"), Asc(","), Asc("."), _
           Asc(" "), Asc("0") To Asc("9")
          searchme$ = searchme$ & Chr$(KeyAscii)
          KeyAscii = 0
  End Select

  result& = SendMessage(FILE1.hWnd, LB_FINDSTRING, 0, searchme$)
  If result& = -1 Then
      searchme$ = Left$(searchme$, Len(searchme$) - 1)
  Else
      result& = SendMessage(FILE1.hWnd, LB_SELECTSTRING, -1, searchme$)
  End If

Q): Is there any way to pass a variable to a form apart from using global variables?

A): The standard workaround is to put an invisible text box (or caption or any other control that suits your use.) on the target form and access it by:

  Form.textbox = "value"

Then you can use the Change event of that control to do anything you want in that form. Also, check out the Tag property which is a "what-you-want" property where you can hook any string you want onto a control. This property can also be accessed from other modules.

Perhaps a more elegant and flexible way is to use the ArrayPlus ActiveX component to implement a stack or as a property bag.

Q): I get a "file not found" error on the IIF function when I distribute by program. Uh?

A): There's a documentation error in VB 3.0, since the manual does not tell you that the IIF function requires the file MSAFINX.DLL to be distributed with your application. No, IIF is not really a financial function, so go figure.

Q): How do I dial a phone number without using MSCOMM?

A): For 32-bit programming, you can call the phone dialer directly through the API. If you make a standard one-form project with two buttons (OK, Cancel), and two text boxes (txtName and txtNumber), you can use the following code to dial a number:

  Private Declare Function tapiRequestMakeCall Lib "TAPI32.DLL" _
   (ByVal DestAddr$, ByVal AppName As String, ByVal CalledParty As String, _
    ByVal Comment As String) As Long

  Public Sub CallPhone(Number As String, Name As String)
      Dim lRes As Long

      If (Trim(Number) = vbNullString) Then
          MsgBox "Sorry, no phone number supplied"
          Exit Sub
      End If
      If (MsgBox("About to call " & Trim(Name) & " at phone number " & _
          Trim(Number) & vbCrLf & "Do It?", vbYesNo, App.Title) = vbYes) Then
          lRes = tapiRequestMakeCall(Trim(Number), App.Title, Trim(Name), "")
          Debug.Print Now; " CallPhone -> tapiRequestMakeCall Result Code = "; lRes
      End If
  End Sub

  Private Sub cmdCancel_Click()
      Unload Me
  End Sub

  Private Sub cmdDial_Click()
      CallPhone txtNumber.Text, txtName.Text
  End Sub

For a more rough approach, try the following code:

  PhoneNumber$ = "(123) 456-7890"
  Open "COM2:" For Output As #1  ' Or COM1:
  Print #1, "ATDT" & PhoneNumber$ & Chr$(13)
  Close #1

Q): Why doesn't "my string" & Chr$(13) do what I want?

A): You need to also add a Chr$(10) to the line. Or us vbCrLf instead. For example:

  NewString$ = "my string" & vbCrLf

Q): How do I avoid the overflow error when assigning values to my variable?

A): Be wary of the scopes of variables. In particular, be wary of the Integer. It accepts values from -32768 to 32767. Anything else causes an overflow run-time error:

  i% = 30000 + 30000  ' fails!!

There is little reason not to use the Long data type instead, which brings us to some other, more subtle problem. Try this:

  l& = 30000 + 30000  ' fails!! Huh?

The reason for this very odd problem is that VB evaluates the expression internally, using the type of the constants, and in this case it's still Integer. So the run-time error occurs even before it tries to assign the value to the Long type variable. To make it work, you have to do the following:

  i& = 30000& + 30000&  ' ok

While the Long uses two bytes more internal space, this is nothing to worry about. Since the 32-bit CPU actually works with 32-bit long integers internally, it is even a (theoretical) bit faster than the shorter counterpart. So if in doubt, and even if not, stick to Longs.

[Note] Some perfectly sane programmers prefer to create their VB applications using the Variant data type almost exclusively. While that would not solve the actual problem above, it certainly will remove most type-conversion and mismatch problems with VB. The extra execution time and memory overhead is rarely significant.

Q): 'Unable to register <dllname>' error when installing VB onto Windows 95 or Windows 98.

A): Windows 95 and Windows 98 have a maximum registry size of 64k. This limit can be quickly met with the installation of some of the larger applications (i.e. Office 97/2000, VB6, Informix). Most often the problem is related to unneeded and unreferenced string entries in the registry's Shared DLL key. VBNet has a Microsoft utility - shrdll.exe - available for download (less than 28k). Shrdll.exe is used to identify -- and optionally remove -- errant entries in the registry's Shared DLL section. Typically, I have found that using this utility reduces an Office/Win95/Win98 system registry from 64k+ to under 47k, after which installations run correctly.

Another thing I've heard, but cannot verify personally because its what I already do, is that VB6 uses so much shared dll/registry space that it almost needs to be installed first after a clean format of the system. The 64k registry limit exists on 95 and 98 systems. And although this utility is especially helpful on Win95/98 systems, it is equally helpful on NT4 systems as well.

Q): 'Unable to register <dllname>' error when installing an application onto a user's Windows 95 or Windows 98 machine?

A):  See the solution to the above FAQ.

Q): How can I activate a running app, or launch it if it is not running?

A): Declare the FindWindow and BringWindowToTop APIs in a form or module, then use:

  Private Sub Command1_Click()
      Dim hCalcWnd As Long
      Dim x As Long

      hCalcWnd = FindWindow("SciCalc", "Calculator")
      If hCalcWnd = 0 Then
          x = Shell("CALC.EXE", vbNormalFocus)
      Else
          BringWindowToTop(hCalcWnd)
      End If
  End Sub

Q): How can I display an ampersand (&) in a menu item or in a label?

A): The ampersand is a special symbol to windows denoting a keyboard accelerator key (underscoring the ALT<key> used to access the command from the keyboard). To display an actual ampersand in a label or menu, use two ampersands together, i.e. 'Save && Exit' displays as 'Save & Exit'.